M5Stack PDMマイクユニット(U089)

概要

M5Stackのユニット紹介です。今回はPDMマイクユニットです。M5StickCに搭載されているのと同じ形式ですね。

マイクの種類

アナログマイク

M5Stack Fireなどに搭載されているのはアナログマイクです。ADCを定期的に実行してスピーカーからの入力を取り込んでいきます。一番原始的な方式です。仕組みはかんたんなのですがマイクからボードまでの配線が長くなるのでノイズが乗りやすくなります。

PDMマイク

PDMはアナログマイクの欠点であるノイズが乗りやすい配線をデジタル化した信号で送信する方式です。マイクの近くでADCした結果をPDM形式と呼ばれるPWMの親戚みたいなデジタル化信号で送信します。

I2Sマイク

PDMでノイズの乗りにくい通信方式になりましたが、PDM形式はちょっと取り扱いが面倒なプロトコルです。I2Sは一般的なサウンドで使うようなデジタル信号で通信をするプロトコルです。ESP32を使うのであればハードウエアでサポートされているのでそれほど面倒ではありません。

ESP-EYEなどで採用されていますが、信号線が3本必要になるのでGrove接続では利用できません。

商品

上記で購入することができます。

このマイクも小さい形のユニットとなります。コネクタは白いので特殊用途になります。

んー、シールが安っぽいですよね。商品の顔なのでもう少し高くみえるシールを使ったほうがいいのかもしれません。

I2Sと書いてありますが、厳密にはI2Sではありません。ESP32はI2Sという機能の中に本当のI2SとPDMとアナログの3種類を処理できる機能がありますのでI2Sと書いてあると思います。

使い方

上記にM5StickCの内蔵マイクを使ったコードがあったので、これをもとにしてみます。

#include <driver/i2s.h>

#define I2S_NUM             I2S_NUM_0           // 0 or 1
#define I2S_SAMPLE_RATE     16000
#define I2S_BUFFER_SIZE     512
#define I2S_PIN_CLK         I2S_PIN_NO_CHANGE
#define I2S_PIN_WS          33
#define I2S_PIN_DOUT        I2S_PIN_NO_CHANGE
#define I2S_PIN_DIN         32

int16_t i2s_sambles[I2S_BUFFER_SIZE];
void i2sMicInit() {
  i2s_config_t i2s_config = {
    .mode                 = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX | I2S_MODE_PDM),
    .sample_rate          = I2S_SAMPLE_RATE,
    .bits_per_sample      = I2S_BITS_PER_SAMPLE_16BIT,
    .channel_format       = I2S_CHANNEL_FMT_ALL_LEFT,
    .communication_format = I2S_COMM_FORMAT_I2S,
    .intr_alloc_flags     = ESP_INTR_FLAG_LEVEL1,
    .dma_buf_count        = 4,
    .dma_buf_len          = 256,
    .use_apll             = false,
    .tx_desc_auto_clear   = false,
    .fixed_mclk           = 0
  };
  i2s_pin_config_t pin_config = {
    .bck_io_num           = I2S_PIN_CLK,
    .ws_io_num            = I2S_PIN_WS,
    .data_out_num         = I2S_PIN_DOUT,
    .data_in_num          = I2S_PIN_DIN,
  };
  i2s_driver_install(I2S_NUM, &i2s_config, 0, NULL);
  i2s_set_pin(I2S_NUM, &pin_config);
}
void setup() {
  Serial.begin(115200);
  delay(1000);

  i2sMicInit();
}

void loop() {
  size_t bytes_read;
  i2s_read(I2S_NUM, (void *)i2s_sambles, sizeof(i2s_sambles), &bytes_read, portMAX_DELAY);

  // Display only the first data
  Serial.printf("%6d\n", i2s_sambles[0]);
}

変更したのはM5StickCのライブラリ呼び込みをやめて、汎用的なコードにしたのとI2S_PIN_WSとI2S_PIN_DINをM5StickCのGroveポートに変更しています。

実行すると取得した波形の先頭部分のみ出力します。シリアルプロッタで表示することでなんとなくの波形がわかります。若干プラスにオフセットされていますが、内蔵マイクに比べれば原点が0に近いですね。

まとめ

M5Stack Core2、ATOM ECHO、M5StickCで内蔵されているのと同じマイクですので使ったことがある人であれば比較的わかりやすいと思います。

とはいえ、最近マイクが内蔵されているボードが多いので使いみちは難しいです。Core2はスピーカーとマイクの同時利用ができないので常時マイクを使いたい場合には外付けを使う意味はあると思います。

コメント

タイトルとURLをコピーしました