M5StickC(ESP32)による「ELEGOO Arduino用UNO R3スターターキット」を利用したArduino入門 その10 アナログジョイスティックモジュール

現時点の情報です。最新情報はM5StickC非公式日本語リファレンスを確認してみてください。

概要

M5StickC(ESP32)による「ELEGOO Arduino用UNO R3スターターキット」を利用したArduino入門 その9 DHT11 温度湿度センサー

現時点の情報です。最新情報はM5StickC非公式日本語リファレンスを確認してみてください。概要今回は「Lesson 11 DHT11 温度湿度センサー」です。DHT11とは？温湿度センサ　モジュール　ＤＨＴ１１秋月さんだと、上記のセンサー...

lang-ship.com

2020.05.15

前回は温湿度センサーでした。今回はアナログジョイスティックになります。

アナログジョイスティックとは？

• ２軸ジョイスティックモジュール　センタープッシュ有り　ケーブル付

秋月さんだと上記のような商品になります。PS2以降に搭載されているジョイスティックなどと同じような操作になります。スティックを左右、上下に動かすことができて、指を離すと中央に戻ります。スティック自体を押し込むことでボタンとしても操作可能です。

構造的には可変抵抗がX軸とY軸で2つはいっており、動かすことで抵抗値がかわり、結果として信号ピンに電圧が変化して測定可能です。スティックの押し込みに関しては、押し込むことでスイッチ用の信号線がGNDと接触して、信号が落ちます。そのためスティックの押し込みボタンを使う場合にはプルアップされている必要があります。

接続方法

図で使っているジョイスティックは、キットに付属していたのとピン配置が違っているので注意してください。

ジョイスティック端子	用途	M5StickC
GND	GND	GND
+5V	基準電圧	3V3
VRx	X軸電圧	GPIO26
VRy	Y軸電圧	GPIO36
SW	スイッチ	GPIO0

気をつける必要があるのがVCCです。ジョイスティックには+5Vと書かれていますが、ジョイスティックを端まで倒した場合に、抵抗が0となりその電圧が信号PINに流れてきます。ESP32は3.3Vで動いているので、接続も3.3Vにする必要があります。5Vを接続すると、ジョイスティック中央の場合2.5Vが信号線に戻ってきますので、中心がずれてしまいます。

スケッチ

void setup() {
  Serial.begin(115200);
  pinMode(26, ANALOG);
  pinMode(36, ANALOG);
  pinMode(0, INPUT); // GPIO0はすでにプルアップ状態、他のPINだとINPUT_PULLUPにする
}
void loop() {
  Serial.printf("X=%d, y=%d, sw=%d\n", analogRead(26), analogRead(36), digitalRead(0));
  delay(100);
}

単純な動作検証用のコードになります。今回スイッチはGPIO0に接続しています。GPIO0は特殊なPINで、基本的に常にプルアップされている端子になります。起動時にLOWの場合にファームウエアの書き込みモードになる端子なので、スイッチを押し込んだままESP32を再起動すると、以下のメッセージが表示されます。

rst:0x1 (POWERON_RESET),boot:0x0 (DOWNLOAD_BOOT(UART0/UART1/SDIO_FEI_FEO_V2))
waiting for download

基本的には使わない方がよい端子なのですが、M5StickCの場合には端子数が少ないので仕方ありません。ただし、起動時にLOWになっていると、正常に起動しなくなるのを覚えておいてください。

GPIO0以外に接続した場合には、プルアップしておく必要があるのでpinModeをINPUT_PULLUPにするのを忘れないでください。もしくは、外部回路でプルアップをする必要があります。

動作させてみる

X=4095, y=4095, sw=1
X=2058, y=4095, sw=1
X=1962, y=4095, sw=1
X=0, y=4095, sw=1
X=0, y=4095, sw=1
X=0, y=3639, sw=1
X=0, y=0, sw=1
X=1186, y=0, sw=1
X=1968, y=0, sw=1
X=4095, y=0, sw=1
X=4095, y=0, sw=1
X=1968, y=1847, sw=1
X=1968, y=1847, sw=1
X=1968, y=1851, sw=1
X=1967, y=1847, sw=1
X=1968, y=1849, sw=1
X=1968, y=1847, sw=0
X=1968, y=1849, sw=0
X=1969, y=1849, sw=1
X=1968, y=1847, sw=1
X=1968, y=1850, sw=1
X=1968, y=1847, sw=1

上記のような出力がシリアル出力に出たと思います。X軸とY軸はセンサーによって方向が違うので注意してください。

X軸とY軸は何もしていないと中央値の2048前後、端っこまで倒すと最小値の0から、最大値の4095まで変化していました。スティックのボタンはいつもは1ですが、押し込むと0になっています。

気をつけないといけないのは、結構中央値などがずれてしまいます。2048を中央と定義して、差分で移動してしまうと常に移動し続けてしまうことになります。

補正版(-8から8までの17段階)

void setup() {
  Serial.begin(115200);
  pinMode(26, ANALOG);
  pinMode(36, ANALOG);
  pinMode(0, INPUT); // GPIO0はすでにプルアップ状態、他のPINだとINPUT_PULLUPにする
}
void loop() {
  int x = analogRead(26);
  int xd = (x - 2048) / 255;
  int y = analogRead(36);
  int yd = (y - 2048) / 255;
  Serial.printf("X=%d(%d), y=%d(%d), sw=%d\n", x, xd, y, yd, digitalRead(0));
  delay(100);
}

-8から8までの移動量に補正をしたスケッチです。中央がそれほどずれていないジョイスティックの場合には中央値は2048で、そこからの差分を少し丸めて取得すればそれっぽい数値になるはずです。

このコードの場合、ほんの少し動かした場合には反応しませんので、微妙な入力で使う場合には、起動時にチュートラルの場合の数値を保存しておき、その値を中央地にしてから補正したほうが正確になります。

ただし、アナログ値なので動かしていなくても結構数値は動くのは、あまり厳密な用途には向いていません。

センター補正スケッチ(-128から128)

int xc;
int yc;
void setup() {
  Serial.begin(115200);
  pinMode(26, ANALOG);
  pinMode(36, ANALOG);
  pinMode(0, INPUT); // GPIO0はすでにプルアップ状態、他のPINだとINPUT_PULLUPにする
  xc = analogRead(26);
  yc = analogRead(36);
}
void loop() {
  int x = analogRead(26);
  int xd = (x - xc) / 14; // 補正によって極値にならない可能性があるので14
  int y = analogRead(36);
  int yd = (y - yc) / 14; 
  // 14で割っているので、極値以上になっているのを極値に修正
  if (xd < -128) {
    xd = -128;
  }
  if (128 < xd) {
    xd = 128;
  }
  if (yd < -128) {
    yd = -128;
  }
  if (128 < yd) {
    yd = 128;
  }
  Serial.printf("X=%4d(%4d), y=%4d(%4d), sw=%d\n", x, xd, y, yd, digitalRead(0));
  delay(100);
}

起動時に取得した数値をセンターとして補正します。本当は複数回取得して平均をとったほうがいいと思います。また、センターがずれるとはじまで移動しても値が中途半端になる可能性があるので、判定の幅も小さくする必要があります。

ある程度はうまく動くと思いますが、アナログでジャンパー接続をしているとノイズなどの影響で変な値を拾ってしまうので、動かしていなくても-2などがでてくることがあります。

その他のセンサー

上記はM5Stack社のジョイスティックユニットです。M5StickのHY2.04P端子(Grove端子)にケーブルで接続することができます。ケーブルで接続する以外にも、直接本体に接続するジョイスティックHATもあります。

M5StickCのJoystick HATをためす

現時点の情報です。最新情報はM5StickC非公式日本語リファレンスを確認してみてください。概要日本未発売のJoystick HATを一ヶ月前に購入していましたが、放置していたので触ってみました。外観箱はいつものプラケース入りです。付属品は...

lang-ship.com

2020.01.07

このユニットの中身はアナログジョイスティックなのですが、中に制御用ICがはいっていて、I2Cで接続しています。そのため、複数のI2Cユニットを接続することも可能です。

原理的には同じなのですが、基板で配線されているのでノイズの影響を受けにくい分ユニットのほうが精度は高いかもしれません。

まとめ

ジョイスティックは個体差があるので、すこし緩めの制御にしたほうが安全だと思います。厳し目の設定にすると、移動していないのに動いたり、端に移動しているつもりなのに移動できていなかったりと問題が発生してしまいます。

続編

M5StickC(ESP32)による「ELEGOO Arduino用UNO R3スターターキット」を利用したArduino入門 その11 赤外線受信モジュール

現時点の情報です。最新情報はM5StickC非公式日本語リファレンスを確認してみてください。概要前回はジョイスティックでした。今回は赤外線受信センサーです。赤外線受信センサーとは？赤外線リモコン受信モジュールＯＳＲＢ３８Ｃ９ＡＡ（２個入）秋...

lang-ship.com

2020.05.25